[ABAP] SELECT 할 때 데이터 가공없이 바로 아이콘 넣기 (CASE WHEN 사용)

🚩 TOP에 선언한 ICON을 더블클릭 해보기

 

이런 화면으로 이동되는데 여기서 자기가 사용할 아이콘이 정의된 이름을 찾는다!

이제 우리는 초록색으로 된 부분을 사용할거임~

 

 

 

🚩 원하는 데이터 SELECT 하기

SELECT CARRID,
       CONNID,
       SEATSOCC,
  CASE WHEN SEATSOCC > 0 THEN '@08@' "ICON_GREEN_LIGHT.
                         ELSE '@0A@' "ICON_RED_LIGHT.
  END AS STATUS
  FROM SFLIGHT
 WHERE CARRID = 'AA'
  INTO TABLE @DATA(LT_DATA).

 

남은 좌석이 0이상인 데이터는 초록색, 그 외엔 빨간색 신호등으로 보여주고 싶다면 이런식으로 사용 가능

디버깅을 해보면 이렇게 신호등이 바로 들어오는걸 볼 수 있당

 

 

 

 

🚩 기존 방법대로 했다면?

TYPES : BEGIN OF LTY_DATA,
          CARRID   TYPE SFLIGHT-CARRID,
          CONNID   TYPE SFLIGHT-CONNID,
          SEATSOCC TYPE SFLIGHT-SEATSOCC,
          STATUS   TYPE ICON_D,
        END OF LTY_DATA.

DATA : LT_DATA TYPE TABLE OF LTY_DATA.

SELECT CARRID,
       CONNID,
       SEATSOCC
  FROM SFLIGHT
 WHERE CARRID = 'AA'
  INTO CORRESPONDING FIELDS OF TABLE @LT_DATA.

 

번거롭게 먼저 데이터 선언을 하고

 

LOOP AT LT_DATA INTO DATA(LS_DATA).
  IF LS_DATA-SEATSOCC > 0.
    LS_DATA-STATUS = ICON_GREEN_LIGHT.
  ELSE.
    LS_DATA-STATUS = ICON_RED_LIGHT.
  ENDIF.

  MODIFY LT_DATA FROM LS_DATA.
ENDLOOP.

 

루프를 돌아가며 하나씩 넣어줬을 것

자매품으로

 

LOOP AT LT_DATA ASSIGNING FIELD-SYMBOL(<FS_DATA>).
  IF <FS_DATA>-SEATSOCC > 0.
    <FS_DATA>-STATUS = ICON_GREEN_LIGHT.
  ELSE.
    <FS_DATA>-STATUS = ICON_RED_LIGHT.
  ENDIF.
ENDLOOP.

 

필드심볼이 있음

이건 MODIFY를 안해줘도 되니까 편함

결과는?

 

 

똑같다~!